5 CLS : PRINT "********************CRAPS*******************"
10 PRINT "If a player rolls a 2,3 or a 12 on his first roll, he loses."
20 PRINT "A 7 or 11 on the first roll is an automatic win."
30 PRINT "Otherwise, the dice are rolled until the total of the"
40 PRINT "first roll is rolled again, in which case the player"
50 PRINT "wins, or a 7 or 11 is rolled, in which case the player"
60 PRINT "CRAPS OUT (loses)."
70 B = 500
80 PRINT "Your account stands at $"; B
90 PRINT "$5000 breaks the bank!"
100 INPUT "How much do you wish to bet"; C
110 IF C > B THEN PRINT "You don't have that much hotshot!": GOTO 80
120 IF C <= 0 GOTO 80
130 INPUT "Press enter for your first roll"; A$
135 CLS
140 PRINT "first roll:";
150 Y = INT(RND * (6)) + 1: Z = INT(RND * (6)) + 1
160 PRINT : PRINT Y, Z: PRINT
170 T = Y + Z: PRINT "Total---->"; T
180 IF (T = 2) + (T = 3) + (T = 12) GOTO 300
190 IF (T = 7) + (T = 11) GOTO 400
200 PRINT T; " is your point! &-)"
210 INPUT "Press enter for your next roll."; A$: CLS
220 Y = INT(RND * (6)) + 1: Z = INT(RND * (6)) + 1: U = Y + Z
230 PRINT "****ROLL****"
240 PRINT Y, Z
250 PRINT "Total---->"; U
260 IF U = T GOTO 450
270 IF (U = 7) + (U = 11) GOTO 350
280 PRINT "Not your point, keep rolling the bones!";
290 GOTO 210
300 IF T = 2 THEN PRINT "****SNAKE EYES****"
310 IF T = 3 THEN PRINT "****COCK EYES****"
320 IF T = 12 THEN PRINT "****BOXCARS****"
330 GOTO 360
350 PRINT "You crapped out! :-("
360 PRINT "You lose your bet! :-(": B = B - C
370 IF B <= 0 GOTO 600
380 GOTO 80
400 PRINT "A natural! :-)"
410 GOTO 460
450 PRINT "Yes! You hit your point! :-)"
460 PRINT "you win your bet! :-)": B = B + C
470 IF B >= 5000 GOTO 620
480 GOTO 80
600 PRINT "And you're out of money. Too bad :-("
610 END
620 PRINT "Hey!! You've broken the bank with $"; B
630 END

